@echo off

rem Silent install and system registration using hostname

if [%1]==[] goto Usage
if [%2]==[] goto Usage

rem Check if installer is Replication_Agent_Setup or ZettaMirrorSetup

if exist Replication_Agent_Setup*.msi (
  set installer=Replication_Agent_Setup*.msi
  set register=Replicagent_Message.exe
) else (
  set installer=ZettaMirrorSetup*msi
  set register=ZettaMirror_Message.exe
)

rem Version wild card for installer file (in current directory)
set iname=
for /f "tokens=*" %%i in ('dir /b "%installer%"') do set iname=%%i
if [%iname%]==[] (
  @echo No installer found
  exit /b 1
)

rem Use hostname for system name
for /f %%i in ('hostname') do set sysname=%%i

rem Install
msiexec /package %iname% /quiet /norestart
if not [%errorlevel%]==[0] (
  @echo %errorlevel% Failed package installation.  Please retry the installation using an administrator login and/or ensuring to run the command prompt as administrator.
  exit /b 1
)

rem Register system with SMP
if [%3]==[] (
  @echo Register individual
  "C:\Program Files\Replication Agent\%register%" -z --zmuser %1 --zmpassword %2 --zmsystemname %sysname%
) else (
  @echo Register under MSP org %3
  "C:\Program Files\Replication Agent\%register%" -z --zmuser %1 --zmpassword %2 --zmsystemname %sysname% --zmorgid %3
)
if not [%errorlevel%]==[0] (
  @echo Failed system registration
  exit /b 1
)

@echo Installed and registered
exit /b 0

:Usage
@echo Usage: (script) user-id password [MSG-org]
exit /b 1
\